PRO RDTMP,Inputfile,time,raw,conv,files
;+
;
; NAME:	
;	RDTMP
; PURPOSE: 
;	Reads in a time ordered list of temperatures
; CATEGORY: 
;	Verification Tool
; CALLING SEQUENCE: 
;	RDTMP,Inputfile,time,raw,conv,files
; INPUTS:  
;	Inputfile = Name of temperature file to read.  Path name is 
;		    post/timelist/Inputfile
; OPTIONAL INPUT PARAMETERS:
;	None
; OUTPUTS:
;	time:   Array of mission time
;	raw: 	Array of raw data values of the temperature
;  	conv:	Array of temperature in Kelvin
;	files:  Array of filenames in time order
;	All arrays have the same size as the time ordered list.
; OPTIONAL OUTPUT PARAMETERS:
;	None
; KEYWORDS:
;	None
; COMMON BLOCKS:
;	None
; SIDE EFFECTS:
;	None
; RESTRICTIONS:
;	None
; EXAMPLE:
;	rdtmp,'t10strap.list',time,raw,conv,files
; PROCEDURE:
;	Determine size of input file
;	Read in file
; MODIFICATION HISTORY:
;	Created by Laura Ellen Dafoe 14 June 1994
;	Tested by Laura Ellen Dafoe on test log: baptism2 on 25 June 1994.
;		Compared t10strap.list with arrays read in by this routine.
;		Checked 1st and last entries.
; REVISION:
;	1.0
;
;----------------------------------------------------------------------------
;		        D I S R S O F T    (C)  1 9 9 4      
;-----------------------------------------------------------------------------
;-
if (N_PARAMS(0) NE 5) then print,'Call is RDTMP,InputFile,time,raw,conv,files'
Inputfile='post/timelist/'+Inputfile
spawn,'wc '+Inputfile,WC
NumLines=fix(strmid(WC,0,7))
NumLines=NumLines(0)

openr,infile,Inputfile,/get_lun
time=fltarr(NumLines)
raw=intarr(NumLines)
conv=fltarr(NumLines)
files=strarr(NumLines)
a=''

for i=0,NumLines-1 do begin
	readf,infile,format='(g10.4,i7,g10.4,x,a48)',time1,raw1,conv1,a
	time(i)=time1
	raw(i)=raw1
	conv(i)=conv1
	files(i)=strtrim(a,2)
endfor

free_lun,infile

end