PRO RDSTK,time,stack,files
;+
;
; NAME:	
;	RDSTK
; PURPOSE: 
;	Reads in the time ordered list of the queues and stack reported
;	in the Housekeeping data set
; CATEGORY: 
;	Verification Tool
; CALLING SEQUENCE: 
;	RDSTK,time,stack,files
; INPUTS:  
;	None	
; OPTIONAL INPUT PARAMETERS:
;	None
; OUTPUTS:
;	time:   Array of mission time
;  	stack:	Array of max dispatcher queue, alarm queue, telemetry queue,
;		science processing queue, and stack size.  There are 5 
;		columns of time ordered data.
;	files:  Array of filenames in time order
;	All arrays have the same length as the time ordered list.
; OPTIONAL OUTPUT PARAMETERS:
;	None
; KEYWORDS:
;	None
; COMMON BLOCKS:
;	None
; SIDE EFFECTS:
;	None
; RESTRICTIONS:
;	None
; EXAMPLE:
;	rdstk,time,stack,files
; PROCEDURE:
;	Determine size of input file: post/timelist/t06stcks.list
;	Read in file
; MODIFICATION HISTORY:
;	Created by Laura Ellen Dafoe 14 June 1994
;	Tested by Laura Ellen Dafoe on test log: baptism2 on 25 June 1994
;		Manually compared 1st and last records of time ordered list
;		with values read in by this routine.
; REVISION:
;	1.0
;
;----------------------------------------------------------------------------
;		        D I S R S O F T    (C)  1 9 9 4      
;-----------------------------------------------------------------------------
;-
if (N_PARAMS(0) NE 3) then print,'Call is RDSTK,time,stack,files'
InputFile='post/timelist/t06stcks.list'
spawn,'wc '+InputFile,WC
NumLines=fix(strmid(WC,0,7))
NumLines=NumLines(0)

openr,infile,Inputfile,/get_lun
time=fltarr(NumLines)
stack=intarr(NumLines,5)
files=strarr(NumLines)
a=''

for i=0,NumLines-1 do begin
	readf,infile,format='(g10.4,5i7,x,a48)',time1,s1,s2,s3,s4,s5,a
	time(i)=time1
	stack(i,0)=s1
	stack(i,1)=s2
	stack(i,2)=s3
	stack(i,3)=s4
	stack(i,4)=s5
	files(i)=strtrim(a,2)
endfor

free_lun,infile

end