PRO RDDES,time,cycle,az,alt,spin,type,meas
;+
;
; NAME:
;	RDDES
; PURPOSE:
;	Reads in the time ordered list of the Descent Cycle data sets
; CATEGORY:
;	Verification Tool
; CALLING SEQUENCE:
;	RDDES,time,cycle,az,alt,spin,type,meas
; INPUTS:
;	None
; OPTIONAL INPUT PARAMETERS:
;	None
; OUTPUTS:
;	time:	Array of mission time
;	cycle:	Array of descent cycle number
;	az:	Array of starting azimuths for each cycle
;	alt:	Array of starting altitudes for each cycle
;	spin:	Array of starting spin rates for each cycle
;	type:	Array of cycle type, scenario step, and SPM flag.  There are
;		3 columns of time ordered data.
;	meas:	Array of CCD, IR, and Violet measurement numbers.  There are
;		3 columns of time ordered data.
;	All arrays have the same length as the time ordered list.
; OPTIONAL OUTPUT PARAMETERS:
;	None
; KEYWORDS:
;	None
; COMMON BLOCKS:
;	None
; SIDE EFFECTS:
;	None
; RESTRICTIONS:
;	None
; EXAMPLE:
;	rddes,time,cycle,az,alt,spin,type,meas
; PROCEDURE:
;	Determine size of input file: post/timelist/t17desc.list
;	Read in file
; MODIFICATION HISTORY:
;	Created by Laura Ellen Dafoe 14 June 1994
;	Tested by Laura Ellen Dafoe on test log: baptism2 on 25 June 1994.
;		Manually compared several records at the beginning and end
;		of the time ordered list with the arrays read by this routine.
; REVISION:
;	1.0	
;
;----------------------------------------------------------------------------
;		        D I S R S O F T    (C)  1 9 9 4      
;-----------------------------------------------------------------------------
;-
if (N_PARAMS(0) NE 7) then print,'Call is rddes,time,cycle,az,alt,spin,type,meas'
InputFile='post/timelist/t17desc.list'
spawn,'wc '+InputFile,WC
NumLines=fix(strmid(WC,0,7))
NumLines=NumLines(0)

openr,infile,Inputfile,/get_lun
time=fltarr(NumLines)
cycle=intarr(NumLines)
az=fltarr(NumLines)
alt=fltarr(NumLines)
spin=fltarr(NumLines)
type=intarr(NumLines,3)
meas=intarr(NumLines,3)

for i=0,NumLines-1 do begin
	readf,infile,format='(g10.4,i4,3g10.1,6i5)',time1,cyc,az1,alt1,$
		spin1,type1,type2,type3,meas1,meas2,meas3
	time(i)=time1
	cycle(i)=cyc
	az(i)=az1
	alt(i)=alt1
	spin(i)=spin1
	type(i,0)=type1
	type(i,1)=type2
	type(i,2)=type3
	meas(i,0)=meas1
	meas(i,1)=meas2
	meas(i,2)=meas3
endfor

free_lun,infile

end